
Credo checks that catch AI-generated code slop in Elixir.
40 checks for patterns that LLMs produce but experienced Elixir developers
don't — blanket rescues, narrator docs, obvious comments, anti-idiomatic
Enum usage, try/rescue around non-raising functions, N+1 queries, and more.
Most checks avoid built-in Credo overlap: Credo never inspects doc/comment
content, doesn't catch Ecto anti-patterns or identity passthrough, and its
MapInto / CaseTrivialMatches checks are disabled or deprecated. A few
semantic-performance checks intentionally overlap with useful Credo refactors
so ExSlop can serve generated-code validation pipelines.
Installation
Add to mix.exs:
def deps do
  [
    {:ex_slop, "~> 0.1", only: [:dev, :test], runtime: false}
  ]
end
Register the plugin in your .credo.exs:
# .credo.exs
%{
  configs: [
    %{
      name: "default",
      plugins: [{ExSlop, []}]
    }
  ]
}
This enables 31 high-signal checks automatically and leaves noisier style/performance checks opt-in.
[!IMPORTANT]
The plugins: line only enables the checks when your config does not
declare an explicit checks.enabled list. If you ran mix credo.gen.config,
your .credo.exs has a full enabled: list, and Credo treats it as
authoritative — it discards the checks the plugin registers, so the plugin
contributes nothing. Append the recommended set to your enabled: list
instead:
checks: %{
  enabled: [
    # ...your existing checks...
  ] ++ Enum.map(ExSlop.recommended_checks(), &{&1, []}),
  # ...
}
ExSlop prints a warning when it detects this situation.

Or cherry-pick individual checks — append them to the extra list:
# .credo.exs
{ExSlop.Check.Warning.BlanketRescue, []},
{ExSlop.Check.Warning.RescueWithoutReraise, []},
{ExSlop.Check.Warning.RepoAllThenFilter, []},
{ExSlop.Check.Warning.QueryInEnumMap, []},
{ExSlop.Check.Warning.GenserverAsKvStore, []},
{ExSlop.Check.Warning.PathExpandPriv, []},
{ExSlop.Check.Warning.DualKeyAccess, []},

{ExSlop.Check.Refactor.FilterNil, []},
{ExSlop.Check.Refactor.RejectNil, []},
{ExSlop.Check.Refactor.ReduceAsMap, []},
{ExSlop.Check.Refactor.MapIntoLiteral, []},
{ExSlop.Check.Refactor.IdentityPassthrough, []},
{ExSlop.Check.Refactor.IdentityMap, []},
{ExSlop.Check.Refactor.CaseTrueFalse, []},
{ExSlop.Check.Refactor.TryRescueWithSafeAlternative, []},
{ExSlop.Check.Refactor.WithIdentityElse, []},
{ExSlop.Check.Refactor.WithIdentityDo, []},
{ExSlop.Check.Refactor.SortThenReverse, []},
{ExSlop.Check.Refactor.StringConcatInReduce, []},
{ExSlop.Check.Refactor.ReduceMapPut, []},
{ExSlop.Check.Refactor.RedundantBooleanIf, []},
{ExSlop.Check.Refactor.FlatMapFilter, []},
{ExSlop.Check.Refactor.RedundantEnumJoinSeparator, []},
{ExSlop.Check.Refactor.UseMapJoin, []},
{ExSlop.Check.Refactor.PreferEnumSlice, []},
{ExSlop.Check.Refactor.GraphemesLength, []},
{ExSlop.Check.Refactor.ManualStringReverse, []},
{ExSlop.Check.Refactor.SortThenAt, []},
{ExSlop.Check.Refactor.SortForTopK, []},
{ExSlop.Check.Refactor.ListFold, []},
{ExSlop.Check.Refactor.ListLast, []},
{ExSlop.Check.Refactor.LengthInGuard, []},
{ExSlop.Check.Refactor.LengthComparison, []},
{ExSlop.Check.Refactor.ExplicitSumReduce, []},
{ExSlop.Check.Readability.NarratorDoc, []},
{ExSlop.Check.Readability.DocFalseOnPublicFunction, []},
{ExSlop.Check.Readability.BoilerplateDocParams, []},
{ExSlop.Check.Readability.ObviousComment, [additional_keywords: []]},
{ExSlop.Check.Readability.StepComment, []},
{ExSlop.Check.Readability.NarratorComment, []},
{ExSlop.Check.Readability.UnaliasedModuleUse, []}
Cherry-pick only the checks that make sense for your project.
Checks
Warnings
	Check	What it catches
	BlanketRescue	rescue _ -> nil or rescue _e -> {:error, "..."}
	RescueWithoutReraise	rescue e -> Logger.error(...); :error — logs but swallows
	RepoAllThenFilter	Repo.all(User) |> Enum.filter(& &1.active) — filter in SQL
	QueryInEnumMap	Enum.map(users, fn u -> Repo.get(...) end) — N+1 query
	GenserverAsKvStore	GenServer that's just Map.get/Map.put on state — use ETS or Agent
	PathExpandPriv	Path.expand("...priv...", __DIR__) — use Application.app_dir/2
	DualKeyAccess	Map.get(m, :key) || Map.get(m, "key"), get_in(m, [:key]) || get_in(m, ["key"]), or m[:key] || m["key"] — normalize once instead

Refactoring
	Check	Bad	Good
	FilterNil	Enum.filter(fn x -> x != nil end)	Enum.reject(&is_nil/1)
	RejectNil	Enum.reject(fn x -> x == nil end)	Enum.reject(&is_nil/1)
	ReduceAsMap	Enum.reduce([], fn x, acc -> [f(x) | acc] end)	Enum.map(&f/1)
	MapIntoLiteral	Enum.map(...) |> Enum.into(%{})	Map.new(...)
	IdentityPassthrough	case r do {:ok, v} -> {:ok, v}; {:error, e} -> {:error, e} end	r
	IdentityMap	Enum.map(fn x -> x end)	remove the call
	CaseTrueFalse	case flag do true -> a; false -> b end	if flag, do: a, else: b
	TryRescueWithSafeAlternative	try do String.to_integer(x) rescue _ -> nil end	Integer.parse(x)
	WithIdentityElse	with {:ok, v} <- f() do v else {:error, r} -> {:error, r} end	drop the else
	WithIdentityDo	with {:ok, v} <- f() do {:ok, v} end	f()
	SortThenReverse	Enum.sort() |> Enum.reverse()	Enum.sort(:desc)
	StringConcatInReduce	Enum.reduce("", fn x, acc -> acc <> x end)	Enum.join/1 or IO data
	ReduceMapPut	Enum.reduce(%{}, fn x, acc -> Map.put(acc, k, v) end)	Map.new/2
	RedundantBooleanIf	if cond, do: true, else: false	use the condition directly
	FlatMapFilter	Enum.flat_map(fn x -> if cond, do: [x], else: [] end)	Enum.filter/2
	RedundantEnumJoinSeparator	Enum.join(parts, "")	Enum.join(parts)

	UseMapJoin	`Enum.map(...)	> Enum.join(...)`	Enum.map_join(...)
	PreferEnumSlice	`Enum.drop(n)	> Enum.take(k)`	Enum.slice(enum, n, k)
	GraphemesLength	`String.graphemes(s)	> length()`	String.length(s)

| ManualStringReverse | String.graphemes(s) |> Enum.reverse() |> Enum.join() | String.reverse(s) |
| SortThenAt | Enum.sort() |> Enum.at(0) | Enum.min/1, Enum.max/1, or selection logic |
| SortForTopK | Enum.sort() |> Enum.take(1) | Enum.min/1, Enum.max/1, or top-k selection |
| ListFold | List.foldl(list, acc, fun) | Enum.reduce(list, acc, fun) |
| ListLast | List.last(list) | avoid needing the last element after traversal |
| LengthInGuard | def f(xs) when length(xs) == 0 | pattern match on [] / [_ | _] |
| LengthComparison | if length(xs) == 0, length(xs) <= 5 (any context) | pattern match, or Enum.count_until/2 for a threshold |
| ExplicitSumReduce | Enum.reduce(nums, 0, fn n, acc -> n + acc end) | Enum.sum(nums) |
Readability
	Check	What it catches
	NarratorDoc	@moduledoc "This module provides functionality for..."
	DocFalseOnPublicFunction	Multiple @doc false on def in one module — cargo-culted
	BoilerplateDocParams	## Parameters\n- conn: The connection struct
	ObviousComment	# Fetch the user above Repo.get(User, id)
	StepComment	# Step 1: Validate input
	NarratorComment	# Here we fetch the user / # Now we validate / # Let's create
	UnaliasedModuleUse	Credo.Code.prewalk used 2+ times without alias Credo.Code

Recommended Credo Built-in Checks
These Credo built-in checks are especially good at catching AI slop.
Enable them in your .credo.exs if you haven't already:
# Catches length(list) == 0 (traverses entire list) → use list == [] or Enum.empty?/1
{Credo.Check.Warning.ExpensiveEmptyEnumCheck, []},

# Catches acc ++ [item] (O(n²) append) → use [item | acc] then Enum.reverse
{Credo.Check.Refactor.AppendSingleItem, []},

# Catches !!var (double negation) — LLMs use this to "cast to boolean"
{Credo.Check.Refactor.DoubleBooleanNegation, []},

# Catches case x do true -> a; false -> b end → if/else
{Credo.Check.Refactor.CondStatements, []},

# Catches Enum.map |> Enum.map → single Enum.map
{Credo.Check.Refactor.MapMap, []},

# Catches Enum.filter |> Enum.filter → single Enum.filter
{Credo.Check.Refactor.FilterFilter, []},

# Catches Enum.reject |> Enum.reject → single Enum.reject
{Credo.Check.Refactor.RejectReject, []},

# Catches Enum.count(enum) > 0 → Enum.any?/1
{Credo.Check.Refactor.FilterCount, []},

# Catches negated conditions in unless → rewrite with positive condition
{Credo.Check.Refactor.NegatedConditionsInUnless, []},

# Catches unless x do .. else .. end → if/else (clearer)
{Credo.Check.Refactor.UnlessWithElse, []}
Credits
Several semantic-performance checks are inspired by Credence, an MIT-licensed standalone semantic linter for generated Elixir code.
Part of Elixir Vibe
ExSlop catches patterns that AI code generation over-produces — it lints the generator, not the language.
It is one building block of a larger stack — tools that make AI-generated
software checkable: structural search, dependence analysis, duplication and
slop detection, session replay, and ecosystem-wide code search. See the
Elixir Vibe organization for the rest, and
Building Blocks for the Future Web
for the thesis, architecture, and roadmap that tie them together.
License
MIT

MIT License

Copyright (c) 2026 Danila Poyarkov

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.

Credo plugin that catches AI-generated code slop in Elixir.
Setup
Add to your .credo.exs:
%{configs: [%{name: "default", plugins: [{ExSlop, []}]}]}
Or cherry-pick individual checks in checks.enabled — see README.md.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of low and works with any version of Elixir.
Explanation
@doc strings with a ## Parameters section that merely restates
the function signature add no value.
# bad
@doc """
Renders the index page.

## Parameters

- conn: The connection struct
- params: A map of parameters
"""
def index(conn, params)

# good — document constraints, not names
@doc """
Renders the index page.

## Parameters

- params: Must include `"page"` (integer >= 1) and
  optionally `"per_page"` (default 20, max 100).
"""

# good — no ## Parameters section at all
@doc """
Renders the index page, paginated.
"""
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of low and works with any version of Elixir.
Explanation
Multiple @doc false on public functions in the same module is a
code smell — typically cargo-culted from Phoenix generators.
A single @doc false is a deliberate choice. But when an LLM
sprays it across every function, it's hiding the API surface.
# bad — every public function has @doc false
defmodule MyAppWeb.UserController do
  @doc false
  def index(conn, _params), do: ...

  @doc false
  def show(conn, %{"id" => id}), do: ...

  @doc false
  def create(conn, %{"user" => params}), do: ...
end

# good — either document or make private
defmodule MyAppWeb.UserController do
  def index(conn, _params), do: ...
  def show(conn, %{"id" => id}), do: ...
end
Check-Specific Parameters
Use the following parameters to configure this check:
:min_count
  Minimum @doc false count per module to trigger (default: 2).
This parameter defaults to 2.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of low and works with any version of Elixir.
Explanation
Inline comments that narrate code in first-person plural ("we") or
with "Let's" / "Here we" are a hallmark of LLM-generated code.
They add no value — either delete them or replace with a comment
that explains WHY.
# bad
# Here we fetch the user from the database
user = Repo.get!(User, id)

# Now we validate the input
changeset = User.changeset(user, attrs)

# Let's create a new changeset
changeset = change(user)

# good — no comment needed, the code is clear

# good — explains WHY
# Bypass validation for admin imports (they're pre-validated upstream)
Repo.insert!(changeset, skip_validations: true)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Readability.NarratorDoc 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of low and works with any version of Elixir.
Explanation
@moduledoc and @doc that begin with "This module/function provides..."
are narrator comments — they restate what the module or function name
already says.
# bad
@moduledoc """
This module provides functionality for handling user authentication.
"""
defmodule MyApp.Auth do

# bad
@doc """
This function creates a new user.
"""
def create_user(attrs)

# good — explain WHY, not WHAT
@moduledoc """
Wraps Bcrypt and session token generation.
Rate-limits login attempts per IP via a sliding window.
"""

# good — document behavior, constraints, examples
@doc """
Passwords must be at least 12 characters. Returns
`{:error, :weak_password}` for common dictionary words.

## Examples

    iex> create_user(%{email: "a@b.c", password: "hunter2"})
    {:error, :weak_password}
"""
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of low and works with any version of Elixir.
Explanation
Comments that restate what the next line of code does are noise.
This check only flags very short comments (under 60 chars) that
start with a verb + article and contain no technical detail.
# bad
# Fetch the user
user = Repo.get(User, id)

# Create the changeset
changeset = User.changeset(user, attrs)

# Return the result
{:ok, changeset}

# good — no comment needed, the code is clear

# good — explains HOW or WHY (not flagged despite starting with "Fetch")
# Fetch the connection from the pool, blocking up to 5s
conn = ConnectionPool.checkout!(pool, timeout: 5_000)
Check-Specific Parameters
Use the following parameters to configure this check:
:additional_keywords
  Additional string prefixes or regexes to match against the comment text after #.
This parameter defaults to [].
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of low and works with any version of Elixir.
Explanation
"Step 1: ..." comments indicate the function is doing too much.
Extract each step into its own well-named function.
# bad
def process(data) do
  # Step 1: Validate the input
  validated = validate(data)
  # Step 2: Transform the data
  transformed = transform(validated)
  # Step 3: Save to database
  save(transformed)
end

# good — the pipe IS the steps
def process(data) do
  data
  |> validate()
  |> transform()
  |> save()
end
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of low and works with any version of Elixir.
Explanation
LLMs tend to paste the same fully-qualified module name into every
call inside a function body. A single Credo.Code.prewalk is fine;
five of them in one function is unreadable slop.
Unlike Credo's AliasUsage (which flags every nested call and
excludes ~50 stdlib lastnames by default), this check only fires
when a module is used repeatedly within a single function body.
# bad — AI slop (3+ uses in one function)
def run(source_file) do
  Credo.Code.prewalk(source_file, &walk/2, ctx)
  Credo.Code.remove_metadata(pattern)
  Credo.Code.remove_metadata(body)
end

# good
def run(source_file) do
  alias Credo.Code
  Code.prewalk(source_file, &walk/2, ctx)
  Code.remove_metadata(pattern)
  Code.remove_metadata(body)
end

# fine — only one use, no alias needed
def run(source_file) do
  Credo.Code.prewalk(source_file, &walk/2, ctx)
end
Check-Specific Parameters
Use the following parameters to configure this check:
:min_count
  Minimum uses of a module within a single function body (default: 3).
This parameter defaults to 3.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
A case that matches only on true and false is better expressed
as if/else.
# bad
case some_condition() do
  true -> :yes
  false -> :no
end

# good
if some_condition(), do: :yes, else: :no
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.reduce/3 that only sums values should usually be Enum.sum/1.
# bad
Enum.reduce(nums, 0, fn num, acc -> num + acc end)

# good
Enum.sum(nums)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.FilterNil 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.filter(fn x -> x != nil end) should be Enum.reject(&is_nil/1).
# bad
list |> Enum.filter(fn x -> x != nil end)
list |> Enum.filter(fn x -> x !== nil end)
list |> Enum.filter(fn x -> !is_nil(x) end)

# good
list |> Enum.reject(&is_nil/1)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.flat_map(list, fn x -> if cond, do: [x], else: [] end) is just
Enum.filter/2 with extra steps.
# bad — flat_map wrapping filter logic in singleton/empty lists
Enum.flat_map(items, fn item ->
  if item.active, do: [item], else: []
end)

# good — use Enum.filter
Enum.filter(items, & &1.active)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
String.graphemes/1 |> length/1 builds an intermediate list just to count it.
# bad
string |> String.graphemes() |> length()
length(String.graphemes(string))

# good
String.length(string)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.map(fn x -> x end) is an identity map that returns the list unchanged.
# bad
list |> Enum.map(fn x -> x end)
Enum.map(list, fn item -> item end)

# good — just remove it
list
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.IdentityPassthrough 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
A case or with that matches patterns only to return the same thing
is a no-op — just return the value directly.
# bad — identity passthrough
case result do
  {:ok, value} -> {:ok, value}
  {:error, reason} -> {:error, reason}
end

# good
result

# bad — with + else that does nothing
with {:ok, result} <- do_something() do
  {:ok, result}
else
  {:error, reason} -> {:error, reason}
end

# good
do_something()
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Comparing length/1 against an integer literal walks the whole list just
to answer a question about its size.
Unlike LengthInGuard, this fires in any context — guard or body — so
moving the comparison out of a guard into an if does not hide the
problem, it just relocates it.
# bad
if length(list) == 0, do: :empty
def page(list) when length(list) > 0, do: ...
length(items) <= 5

# good — emptiness
if list == [], do: :empty          # or Enum.empty?(list)
def page([_ | _]), do: ...

# good — exact/maximum size
case list do
  [_, _] -> ...
end

# good — threshold on a large or lazy enum
Enum.count_until(items, 6) <= 5
length/1 itself is fine when you genuinely need the count (logging,
arithmetic, a value you reuse) — only the comparison against a literal is
flagged.
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.LengthInGuard 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
length/1 in guards traverses the list whenever the clause is considered.
# bad
def empty?(list) when length(list) == 0, do: true

# good
def empty?([]), do: true
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.ListFold 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Prefer Enum.reduce/3 over Erlang-style List.foldl/3 and List.foldr/3.
# bad
List.foldl(items, 0, fn item, acc -> item + acc end)

# good
Enum.reduce(items, 0, fn item, acc -> item + acc end)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.ListLast 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
List.last/1 traverses the whole list. Prefer structuring code so the needed value is already available.
# bad
List.last(items)

# better when you control construction
[last | _] = Enum.reverse(items)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.ManualStringReverse 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
String.graphemes/1 |> Enum.reverse/1 |> Enum.join/1 manually reimplements String.reverse/1.
# bad
string |> String.graphemes() |> Enum.reverse() |> Enum.join()

# good
String.reverse(string)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.MapIntoLiteral 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.map(fn {k, v} -> ... end) |> Enum.into(%{}) should be Map.new/2.
# bad
list
|> Enum.map(fn {k, v} -> {k, transform(v)} end)
|> Enum.into(%{})

# good
Map.new(list, fn {k, v} -> {k, transform(v)} end)
Credo's Refactor.MapInto is disabled for Elixir >= 1.8 (performance
was fixed), but Map.new/2 is still clearer and more intentional.
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.PreferEnumSlice 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.drop/2 |> Enum.take/2 is more clearly expressed as Enum.slice/3.
# bad
items |> Enum.drop(offset) |> Enum.take(limit)

# good
Enum.slice(items, offset, limit)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.ReduceAsMap 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.reduce([], fn x, acc -> [f(x) | acc] end) is just Enum.map/2.
# bad — manually building a reversed list
Enum.reduce(items, [], fn item, acc ->
  [transform(item) | acc]
end)

# bad — O(n²) list concatenation
Enum.reduce(items, [], fn item, acc ->
  acc ++ [transform(item)]
end)

# good
Enum.map(items, &transform/1)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.ReduceMapPut 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.reduce(%{}, fn x, acc -> Map.put(acc, key, value) end) is
Map.new/2 (or a for comprehension).
# bad — verbose reduce to build a map
Enum.reduce(batch, %{}, fn event, acc ->
  Map.put(acc, event.id, event)
end)

# good — use Map.new
Map.new(batch, fn event -> {event.id, event} end)

# good — for comprehension
for event <- batch, into: %{}, do: {event.id, event}
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.RedundantBooleanIf 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
if condition, do: true, else: false is redundant — the condition
already evaluates to a boolean (or can be made one with !!).
# bad — wrapping a boolean condition in if/true/false
is_active = if status == :active, do: true, else: false
if !is_nil(x) and !is_nil(y), do: true, else: false

# good — use the expression directly
is_active = status == :active
!is_nil(x) and !is_nil(y)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.RedundantEnumJoinSeparator 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.join(enum, "") is the same as Enum.join(enum).
# bad
Enum.join(parts, "")
parts |> Enum.join("")

# good
Enum.join(parts)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.RejectNil 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.reject(fn x -> x == nil end) should be Enum.reject(&is_nil/1).
# bad
list |> Enum.reject(fn x -> x == nil end)
list |> Enum.reject(fn x -> x === nil end)
list |> Enum.reject(fn x -> is_nil(x) end)

# good
list |> Enum.reject(&is_nil/1)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.SortForTopK 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Sorting the whole collection just to take a single element does extra work.
# bad
list |> Enum.sort() |> Enum.take(1)
list |> Enum.sort() |> hd()

# good — when only one value is needed
Enum.min(list)
Enum.max(list)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.SortThenAt 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Sorting an entire list only to access one element is often unnecessary.
# bad
list |> Enum.sort() |> Enum.at(0)
Enum.at(Enum.sort(list), 0)

# good — for min/max cases
Enum.min(list)
Enum.max(list)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.SortThenReverse 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.sort/1 |> Enum.reverse/1 should be Enum.sort(:desc).
Enum.sort_by/2 |> Enum.reverse/1 should be Enum.sort_by(fun, :desc).
# bad
list |> Enum.sort() |> Enum.reverse()
Enum.reverse(Enum.sort(list))
list |> Enum.sort_by(&fun/1) |> Enum.reverse()

# good
Enum.sort(list, :desc)
Enum.sort_by(list, &fun/1, :desc)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.StringConcatInReduce 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.reduce/3 that builds a string via <> concatenation is O(n²).
# bad
Enum.reduce(list, "", fn item, acc -> acc <> item end)
Enum.reduce(list, "", fn item, acc -> acc <> to_string(item) end)

# good
Enum.join(list)
Enum.map_join(list, &to_string/1)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.TryRescueWithSafeAlternative 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of high and works with any version of Elixir.
Explanation
try/rescue around a function that has a non-raising equivalent
is a sign the AI doesn't know Elixir's API.
# bad
try do
  String.to_integer(value)
rescue
  _ -> nil
end

# good
case Integer.parse(value) do
  {int, ""} -> int
  _ -> nil
end
Common pairs:
	Raising	Safe alternative
	String.to_integer/1	Integer.parse/1
	String.to_float/1	Float.parse/1
	String.to_atom/1	String.to_existing_atom/1
	Jason.decode!/1	Jason.decode/1
	JSON.decode!/1	JSON.decode/1
	Map.fetch!/2	Map.fetch/2
	Keyword.fetch!/2	Keyword.fetch/2
	Enum.fetch!/2	Enum.fetch/2 / Enum.at/2
	File.read!/1	File.read/1
	File.write!/2	File.write/2
	URI.parse/1 (old)	URI.new/1

Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.UseMapJoin 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Enum.map/2 |> Enum.join/1 creates an intermediate list.
# bad
items |> Enum.map(&to_string/1) |> Enum.join(",")

# good
Enum.map_join(items, ",", &to_string/1)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.WithIdentityDo 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
A with whose do block just returns the matched pattern is redundant —
use the expression directly.
# bad — identity do
with {:ok, result} <- do_something() do
  {:ok, result}
end

# good
do_something()
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Refactor.WithIdentityElse 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
A with whose else clauses all return exactly what they matched
is redundant — remove the else block entirely.
# bad — identity else
with {:ok, result} <- do_something() do
  {:ok, result}
else
  {:error, reason} -> {:error, reason}
end

# good
do_something()
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Warning.BlanketRescue 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of high and works with any version of Elixir.
Explanation
rescue _ -> or rescue _e -> that returns nil or a generic error
tuple swallows all exceptions, making bugs invisible.
This is the most common AI slop pattern in Elixir. The AI adds blanket
rescues to make code "robust", but it actually hides crashes that would
surface real problems.
# bad — swallows everything
try do
  do_something()
rescue
  _ -> nil
end

# bad — generic string loses all context
rescue
  _e -> {:error, "Something went wrong"}

# good — rescue specific exceptions
rescue
  e in [ArgumentError, RuntimeError] ->
    Logger.warning("Failed: #{Exception.message(e)}")
    {:error, :invalid_input}

# good — let it crash (the BEAM way)
do_something()
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Warning.DualKeyAccess 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Checking both atom and string keys for the same field means the data shape
is unknown. This is usually defensive coding where a boundary should
normalize the map once.
# bad — doesn't know if keys are atoms or strings
Map.get(usage, :input_tokens) || Map.get(usage, "input_tokens") || 0
get_in(data, [:path]) || get_in(data, ["path"])
payload[:kind] || payload["kind"]

# good — normalize once at the boundary, then use one key type
Map.get(usage, :input_tokens, 0)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Warning.GenserverAsKvStore 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
A GenServer that implements handle_call({:get, key}, ...) with a body
that just calls Map.get(state, key) is reimplementing a key-value store.
The BEAM already provides Agent and ETS for this.
# bad — GenServer as a dumb key-value wrapper
defmodule MyCache do
  use GenServer

  def handle_call({:get, key}, _from, state) do
    {:reply, Map.get(state, key), state}
  end

  def handle_call({:put, key, value}, _from, state) do
    {:reply, :ok, Map.put(state, key, value)}
  end
end

# good — use Agent
defmodule MyCache do
  use Agent

  def start_link(initial) do
    Agent.start_link(fn -> initial end, name: __MODULE__)
  end

  def get(key), do: Agent.get(__MODULE__, &Map.get(&1, key))
  def put(key, value), do: Agent.update(__MODULE__, &Map.put(&1, key, value))
end

# good — use ETS
:ets.new(:cache, [:named_table, :public])
:ets.insert(:cache, {key, value})
:ets.lookup(:cache, key)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Warning.PathExpandPriv 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
Using Path.expand("...priv...", __DIR__) to locate application resources
is fragile — it depends on the source layout and breaks in releases.
Use Application.app_dir/2 instead.
# bad — fragile, breaks in releases
Path.expand("../../priv/prompts/system.md", __DIR__)

# good — works in dev, test, and releases
Application.app_dir(:my_app, "priv/prompts/system.md")
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Warning.QueryInEnumMap 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of higher and works with any version of Elixir.
Explanation
Calling Repo.get, Repo.one, or Repo.all inside Enum.map/2 is
an N+1 query — one database round-trip per element.
# bad — N+1 queries
users
|> Enum.map(fn user ->
  posts = Repo.all(from p in Post, where: p.user_id == ^user.id)
  %{user | posts: posts}
end)

# good — preload in one query
users |> Repo.preload(:posts)
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Warning.RepoAllThenFilter 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of high and works with any version of Elixir.
Explanation
Repo.all(Schema) |> Enum.filter(...) loads every record into memory
then filters in Elixir. Use Ecto query conditions instead.
# bad — loads all users then filters
Repo.all(User) |> Enum.filter(& &1.active)

# good — filters at the database
User |> where(active: true) |> Repo.all()
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

      




  

    
ExSlop.Check.Warning.RescueWithoutReraise 
    



      
Basics
This check is disabled by default.
Learn how to enable it via .credo.exs.
This check has a base priority of normal and works with any version of Elixir.
Explanation
A rescue that logs the error but doesn't re-raise or return it
silently swallows failures. Callers will never know something went wrong.
# bad — logs then returns a generic atom
rescue
  e ->
    Logger.error("Failed: #{inspect(e)}")
    :error

# good — log and re-raise
rescue
  e ->
    Logger.error("Failed: #{Exception.message(e)}")
    reraise e, __STACKTRACE__

# good — return the actual exception info
rescue
  e in RuntimeError ->
    {:error, Exception.message(e)}
Check-Specific Parameters
There are no specific parameters for this check.
General Parameters
Like with all checks, general params can be applied.
Parameters can be configured via the .credo.exs config file.

